#include <math.h>

#define redLED         9    // controls red LEDs
#define greenLED      10    // controls green LEDs
#define blueLED       11    // controls blue LEDs

int colours[][3] = {
  {255,  0,  0},  // red
  {  0,255,  0},  // greeen
  {  0,  0,255},  // blue
  {255,  0,255},  // fuscia
  {255,102,  0},  // orange
  
  {255, 20,147},  // pink  5
  {148,  0,211},  // violet
  {255,255,255},  // white
  {255,255,  0},  // yellow
  {124,252,  0},  // lime green

  {  0,100,  0},  // dark green  10
  {  0,255,255},  // cyan
  {128,  0,  0},  // maroon
  {128,128,128},  // dark grey
  {  0,  0, 80}   // navy blue
};
const int NUM_COLOURS = ( sizeof(colours) / (sizeof(int)*3) );
int gRandIndex = 0;

void setup()  { 
  
  Serial.begin(57600);
  Serial.println( "Arduino starting LED test" );

  // seed with an unconnected pin
  randomSeed( analogRead(0) );
  
  Serial.println( "Blinking colours" );
   int count=0;
   for( count=0;count<NUM_COLOURS;count++ ) {
      printColour( colours[count] );
      toggleLED( colours[count], 500 );
   }

  Serial.println( "" );
  Serial.println( "Flashing random colours" );
  
  gRandIndex = random(NUM_COLOURS);
} 

void loop()  {   
  int randIndex2;
  
  do {
     randIndex2 = random(NUM_COLOURS);
  } while (gRandIndex == randIndex2 );

  Serial.print( "Fading from " );  
  printColour( colours[gRandIndex] );
  Serial.print( "Fading to   " );
  printColour( colours[randIndex2] );
  Serial.println( "" );

  fadeBetween( colours[gRandIndex], colours[randIndex2], 100 ); 
  clearLEDs( 500 );
  
  gRandIndex = randIndex2;
}

void printColour( int R, int G, int B ) {
   printColour( (int[3]){R,G,B} );
}

void printColour( int colour[3] ) {
   char buffer[100];
   sprintf(buffer,"R: %3d  G: %3d  B: %3d",  colour[0], colour[1], colour[2] ); 
   Serial.println( buffer );
}

void clearLEDs( int delayMS ) {
    analogWrite( redLED, 0 );
    analogWrite( greenLED, 0 );
    analogWrite( blueLED, 0 );
    delay( delayMS );
}

void toggleLED( int colour[3], int delayMS ) {
    analogWrite( redLED, colour[0] );
    analogWrite( greenLED, colour[1] );
    analogWrite( blueLED, colour[2] );
    delay( delayMS );
    
    clearLEDs( delayMS );
}

void flashLED( int colour[3], int seconds ) {
  // toggleLED calls delay(50) x 2 == 100ms
  // 10 x 100ms = 1 second
  for( int i=0;i<(seconds*10);i++ ) {
    toggleLED( colour, 50 );
  }
}

void fadeBetween( int col[3], int col2[3], int steps ) {
  float startR = col[0];
  float stepsR = ((col2[0]-startR) / steps);

  float startG = col[1];
  float stepsG = ((col2[1]-startG) / steps);

  float startB = col[2];
  float stepsB = ((col2[2]-startB) / steps);
  
  //flashLED( col,  2 );
  //flashLED( col2, 2 );
  
  analogWrite( redLED,   (int)startR );
  analogWrite( greenLED, (int)startG );
  analogWrite( blueLED,  (int)startB );
  delay( 2000 );
  
  for( int i=0;i<steps;i++ ) {
    startR += stepsR;
    startG += stepsG;
    startB += stepsB;
    
    analogWrite( redLED,   (int)startR );
    analogWrite( greenLED, (int)startG );
    analogWrite( blueLED,  (int)startB );
    
    delay(100);
  }
  
//  printColour( (int)startR, (int)startG, (int)startB );
  delay(3000);
}