#include <ESP8266WiFi.h>
#include <OneWire.h>

#define NO_ACTION       0
#define BAD_ACTION      1

#define TOGGLE_DOOR1    D1   // weMOS relay pin
#define READ_DISTANCE1  D2
#define READ_TEMP1      D3
#define FORCE_SEND_DATA 9999

#define SERVER_PORT     1234

#define ONEMIN          (1000UL * 60)
// #define pulseTIMER      (ONEMIN / 4)
#define pulseTIMER      (ONEMIN * 10)

/*
 *  Server and oneWire devices 
 */
WiFiServer server(SERVER_PORT);
OneWire    ds(D3);

/*
 *  supported actions 
 */
typedef struct  {
    const char* actionWord;
    int         actionToken;
} ActionArray;

#define NUM_ACTIONS     4
ActionArray actionArray[NUM_ACTIONS] {
    {"toggle1",      TOGGLE_DOOR1},
    {"distance1",    READ_DISTANCE1},
    {"temperature1", READ_TEMP1},
    {"forceSend",    FORCE_SEND_DATA}
};

/*
 *  WIFI connect info
 */
const char* ssid     = "ssid_name";
const char* password = "abc123";

void setup() {
  Serial.begin(9600);
  delay(10);
  
  Serial.println("");
  Serial.print("Connecting to ");
  Serial.println( ssid );

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println( "." );
  
  Serial.println( "WiFi connected.");  
  Serial.print( "IP address: ");
  Serial.println( WiFi.localIP()); 

  pinMode(BUILTIN_LED, OUTPUT);  // initialize onboard LED as output

  pinMode(TOGGLE_DOOR1, OUTPUT);
  digitalWrite(TOGGLE_DOOR1, LOW);

  // Start the server
  server.begin();
  Serial.println("Server started");  
}

void loop() {

  // send data every pulseTIMER minutes
  unsigned static long rolltime = millis() + pulseTIMER;
  if((long)(millis() - rolltime) >= 0) {
    sendData();
    rolltime += pulseTIMER;
  }

  // blink on board led to show the device is working
  digitalWrite(BUILTIN_LED, HIGH);  // turn on LED with voltage HIGH
  delay(1000);                      // wait one second
  digitalWrite(BUILTIN_LED, LOW);   // turn off LED with voltage LOW
  delay(1000);                      // wait one second

  // Check if a client has connected
  WiFiClient client = server.available();
  if (!client) {
    return;
  }
  
  // Wait until the client sends some data
  Serial.println("new client");
  while(!client.available()){
    delay(1);
  }
  
  // Read the first line of the request
  String req = client.readStringUntil('\r');
  client.flush();

  handleRequest(client, req);
}

void handleRequest(WiFiClient& client, String& req) {  
  int action = NO_ACTION;
  for( int i=0;i<NUM_ACTIONS;i++) {
      if( req == actionArray[i].actionWord ) {
          Serial.println( actionArray[i].actionWord );
          action = actionArray[i].actionToken;
      }
  }

  if( action == TOGGLE_DOOR1 ) {
      digitalWrite(TOGGLE_DOOR1, !digitalRead(TOGGLE_DOOR1));
      delay(500);
      digitalWrite(TOGGLE_DOOR1, !digitalRead(TOGGLE_DOOR1));
      
      Serial.println( "door toggled" );
      client.println( "door toggled" );

  }
  else if( action == READ_DISTANCE1 ) {  
    long cm = getDoorDistance(READ_DISTANCE1);
    Serial.println(cm);
    client.println(cm);

  }
  else if( action == READ_TEMP1 ) {
    long cel = getTemperature(READ_TEMP1);
    Serial.println(cel);
    client.println(cel);
    
  }
  else if( action == FORCE_SEND_DATA ) {
    sendData();
    Serial.println("forceSend");
    client.println("force send");

  }
  else {
    Serial.println( "unknown request" );
    
  }
}
  
#define HTTP_SERVER     "homeautomation.somewhere"
#define URI_CGI         "GET /recordGarage.php?distance=%ld&temp=%ld&reading=%d  HTTP/1.1\r\n"

void sendData() {
  long cm = getDoorDistance(READ_DISTANCE1);
  long cel = getTemperature(READ_TEMP1);

  char request[255];
  // sprintf(request,"[{'distance':'%d'},{'temp','%d'}]",cm,cel);
  sprintf(request,URI_CGI,cm,cel,1);
  Serial.print(request);

  WiFiClient rxClient;
  if( rxClient.connect(HTTP_SERVER, 80)) {
    // Serial.println("connected to server");
    // Make a HTTP request:
    rxClient.print(request);
    rxClient.print("Host: ");
    rxClient.println( HTTP_SERVER );
    rxClient.println("Connection: close");
    rxClient.println();
  }

  String result;
  while(rxClient.connected() && !rxClient.available()) delay(1); //waits for data
  while (rxClient.connected() || rxClient.available()) { //connected or data available
    char c = rxClient.read(); //gets byte from ethernet buffer
    result = result+c;
  }

  rxClient.stop(); //stop client
}

// distance from ceiling to door or floor in cm's
long getDoorDistance( int sensor ) {
    pinMode( sensor, OUTPUT );
    
    digitalWrite(sensor, LOW);
    delayMicroseconds(2);
    digitalWrite(sensor, HIGH);
    delayMicroseconds(5);
    digitalWrite(sensor, LOW);

    pinMode(sensor, INPUT);
    long duration = pulseIn(sensor, HIGH); 
  
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return (duration / 29 / 2);
}

long getTemperature( int sensor ) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;

  if ( !ds.search(addr)) {
    ds.reset_search();
    delay(250);
    return -1;
  }
  ds.reset_search();

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return -1;
  }

  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      // Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      // Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      // Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return -1;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, use ds.write(0x44,1) with parasite power on at the end

  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.

  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
  }

  celsius = ( (data[1] << 8) + data[0] )*0.0625;

  return celsius;
}